[ViewVC] Annotation of: cvs/rxvt-unicode/src/perl/tabbed

#! perl

sub refresh {
   my ($self) = @_;

   my $ncol = $self->ncol;

   my $text = " " x $ncol;
   my $rend = [($self->{rs_tabbar}) x $ncol];

   my @ofs;

   substr $text, 0, 7, "[NEW] |";
   @$rend[0 .. 5] = ($self->{rs_tab}) x 6;
   push @ofs, [0, 6, sub { $_[0]->new_tab }];

   my $ofs = 7;
   my $idx = 0;

   for my $tab (@{ $self->{tabs} }) {
      $idx++;

      my $act = $tab->{activity} && $tab != $self->{cur}
                ? "*" : " ";

      my $txt = "$act$idx$act";
      my $len = length $txt;

      substr $text, $ofs, $len + 1, "$txt|";
      @$rend[$ofs .. $ofs + $len - 1] = ($self->{rs_tab}) x $len
         if $tab == $self->{cur};

      push @ofs, [ $ofs, $ofs + $len, sub { $_[0]->make_current ($tab) } ];

      $ofs += $len + 1;
   }

   $self->{tabofs} = \@ofs;

   $self->ROW_t (0, $text, 0, 0, $ncol);
   $self->ROW_r (0, $rend, 0, 0, $ncol);

   $self->want_refresh;
}

sub new_tab {
   my ($self, @argv) = @_;

   # save a backlink to us, make sure tabbed is inactive
   push @urxvt::TERM_INIT, sub {
      my ($term) = @_;
      $term->{parent} = $self;

      for (0 .. urxvt::NUM_RESOURCES - 1) {
         my $value = $self->{resource}[$_];

         $term->resource ("+$_" => $value)
            if defined $value;
      }

      $term->resource (perl_ext_2 => $term->resource ("perl_ext_2") . ",-tabbed");
   };

   push @urxvt::TERM_EXT, urxvt::ext::tabbed::tab::;

   my $term = new urxvt::term
      $self->env, $urxvt::RXVTNAME,
      -embed => $self->parent,
      @argv,
   ;
}

sub configure {
   my ($self) = @_;

   my $tab = $self->{cur};

   # this is an extremely dirty way to force a configurenotify, but who cares
   $tab->XMoveResizeWindow (
      $tab->parent,
      0, $self->{tabheight} + 1,
      $self->width, $self->height - $self->{tabheight}
   );
   $tab->XMoveResizeWindow (
      $tab->parent,
      0, $self->{tabheight},
      $self->width, $self->height - $self->{tabheight}
   );
}

sub on_resize_all_windows {
   my ($self, $width, $height) = @_;

   1
}

sub copy_properties {
   my ($self) = @_;
   my $tab = $self->{cur};

   my $wm_normal_hints = $self->XInternAtom ("WM_NORMAL_HINTS");

   my $current = delete $self->{current_properties};

   # pass 1: copy over properties different or nonexisting
   for my $atom ($tab->XListProperties ($tab->parent)) {
      my ($type, $format, $items) = $self->XGetWindowProperty ($tab->parent, $atom);

      # fix up size hints
      if ($atom == $wm_normal_hints) {
         my (@hints) = unpack "l!*", $items;

         $hints[$_] += $self->{tabheight} for (4, 6, 16);

         $items = pack "l!*", @hints;
      }

      my $cur = delete $current->{$atom};

      # update if changed, we assume empty items and zero type and format will not happen
      $self->XChangeProperty ($self->parent, $atom, $type, $format, $items)
         if $cur->[0] != $type or $cur->[1] != $format or $cur->[2] ne $items;

      $self->{current_properties}{$atom} = [$type, $format, $items];
   }

   # pass 2, delete all extraneous properties
   $self->XDeleteProperty ($self->parent, $_) for keys %$current;
}

sub make_current {
   my ($self, $tab) = @_;

   if (my $cur = $self->{cur}) {
      delete $cur->{activity};
      $cur->XUnmapWindow ($cur->parent) if $cur->mapped;
      $cur->focus_out;
   }

   $self->{cur} = $tab;

   $self->configure;
   $self->copy_properties;

   $tab->focus_out; # just in case, should be a nop
   $tab->focus_in if $self->focus;

   $tab->XMapWindow ($tab->parent);
   delete $tab->{activity};
   $self->refresh;

   ()
}

sub on_focus_in {
   my ($self, $event) = @_;

   $self->{cur}->focus_in;

   ()
}

sub on_focus_out {
   my ($self, $event) = @_;

   $self->{cur}->focus_out;

   ()
}

sub on_tt_write {
    my ($self, $octets) = @_;

    $self->{cur}->tt_write ($octets);

    1
}

sub on_key_press {
   my ($self, $event) = @_;

   $self->{cur}->key_press ($event->{state}, $event->{keycode}, $event->{time});

   1
}

sub on_key_release {
   my ($self, $event) = @_;

   $self->{cur}->key_release ($event->{state}, $event->{keycode}, $event->{time});

   1
}

sub on_button_press {
   1
}

sub on_button_release {
   my ($self, $event) = @_;

   if ($event->{row} == 0) {
      for my $button (@{ $self->{tabofs} }) {
         $button->[2]->($self, $event)
            if $event->{col} >= $button->[0]
               && $event->{col} < $button->[1];
      }
   }

   1
}

sub on_motion_notify {
   1
}

sub on_init {
   my ($self) = @_;

   $self->{resource} = [map $self->resource ("+$_"), 0 .. urxvt::NUM_RESOURCES - 1];

   $self->resource (int_bwidth => 0);
   $self->resource (name => "URxvt.tabbed");
   $self->resource (pty_fd => -1);

   $self->option ($urxvt::OPTION{scrollBar}, 0);

   my $fg    = $self->x_resource ("tabbar-fg");
   my $bg    = $self->x_resource ("tabbar-bg");
   my $tabfg = $self->x_resource ("tab-fg");
   my $tabbg = $self->x_resource ("tab-bg");

   defined $fg    or $fg    = 3;
   defined $bg    or $bg    = 0;
   defined $tabfg or $tabfg = 0;
   defined $tabbg or $tabbg = 1;

   $self->{rs_tabbar} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $fg    + 2, $bg    + 2);
   $self->{rs_tab}    = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $tabfg + 2, $tabbg + 2);

   ()
}

sub on_start {
   my ($self) = @_;

   $self->{tabheight} = $self->int_bwidth + $self->fheight + $self->lineSpace;

   $self->cmd_parse ("\033[?25l");

   my @argv = $self->argv;

   do {
      shift @argv;
   } while @argv && $argv[0] ne "-e";

   $self->new_tab (@argv);

   ()
}

sub on_configure_notify {
   my ($self, $event) = @_;

   $self->configure;
   $self->refresh;

   ()
}

sub on_wm_delete_window {
   my ($self) = @_;

   $_->destroy for @{ $self->{tabs} };

   1
}

sub tab_start {
   my ($self, $tab) = @_;

   $tab->XChangeInput ($tab->parent, urxvt::PropertyChangeMask);

   push @{ $self->{tabs} }, $tab;

#   $tab->{name} ||= scalar @{ $self->{tabs} };
   $self->make_current ($tab);

   ()
}

sub tab_destroy {
   my ($self, $tab) = @_;

   $self->{tabs} = [ grep $_ != $tab, @{ $self->{tabs} } ];

   if (@{ $self->{tabs} }) {
      if ($self->{cur} == $tab) {
         delete $self->{cur};
         $self->make_current ($self->{tabs}[-1]);
      } else {
         $self->refresh;
      }
   } else {
      # delay destruction a tiny bit
      $self->{destroy} = urxvt::iw->new->start->cb (sub { $self->destroy });
   }

   ()
}

sub tab_key_press {
   my ($self, $tab, $event, $keysym, $str) = @_;

   if ($event->{state} & urxvt::ShiftMask) {
      if ($keysym == 0xff51 || $keysym == 0xff53) {
         my ($idx) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };

         --$idx if $keysym == 0xff51;
         ++$idx if $keysym == 0xff53;

         $self->make_current ($self->{tabs}[$idx % @{ $self->{tabs}}]);

         return 1;
      } elsif ($keysym == 0xff54) {
         $self->new_tab;

         return 1;
      }
   }
   elsif ($event->{state} & urxvt::ControlMask) {
      if ($keysym == 0xff51 || $keysym == 0xff53) {
         my ($idx1) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };
         my  $idx2  = ($idx1 + ($keysym == 0xff51 ? -1 : +1)) % @{ $self->{tabs} };

         ($self->{tabs}[$idx1], $self->{tabs}[$idx2]) =
            ($self->{tabs}[$idx2], $self->{tabs}[$idx1]);

         $self->make_current ($self->{tabs}[$idx2]);

         return 1;
      }
   }

   ()
}

sub tab_property_notify {
   my ($self, $tab, $event) = @_;

   $self->copy_properties
      if $event->{window} == $tab->parent;

   ()
}

sub tab_activity {
   my ($self, $tab) = @_;

   $self->refresh;
}

package urxvt::ext::tabbed::tab;

# helper extension implementing the subwindows of a tabbed terminal.
# simply proxies all interesting calls back to the tabbed class.

{
   for my $hook qw(start destroy key_press property_notify) {
      eval qq{
         sub on_$hook {
            my \$parent = \$_[0]{term}{parent}
               or return;
            \$parent->tab_$hook (\@_)
         }
      };
      die if $@;
   }
}

sub on_add_lines {
  $_[0]->{activity}++
     or $_[0]{term}{parent}->tab_activity ($_[0]);
  ()
}


Revision:	1.30
Committed:	Mon Jan 9 17:57:04 2012 UTC (12 years, 4 months ago) by mikachu
Branch:	MAIN
CVS Tags:	rxvt-unicode-rel-9_15
Changes since 1.29:	+2 -4 lines
Log Message:	revert previous commit
#	User	Rev	Content
1	root	1.1	#! perl
2
3			sub refresh {
4			my ($self) = @_;
5
6	root	1.6	my $ncol = $self->ncol;
7
8			my $text = " " x $ncol;
9	root	1.15	my $rend = [($self->{rs_tabbar}) x $ncol];
10	root	1.6
11			my @ofs;
12	root	1.1
13	root	1.7	substr $text, 0, 7, "[NEW] \|";
14	root	1.15	@$rend[0 .. 5] = ($self->{rs_tab}) x 6;
15	root	1.7	push @ofs, [0, 6, sub { $_[0]->new_tab }];
16
17			my $ofs = 7;
18			my $idx = 0;
19
20	root	1.1	for my $tab (@{ $self->{tabs} }) {
21	root	1.7	$idx++;
22
23	root	1.9	my $act = $tab->{activity} && $tab != $self->{cur}
24			? "*" : " ";
25
26			my $txt = "$act$idx$act";
27	root	1.6	my $len = length $txt;
28
29			substr $text, $ofs, $len + 1, "$txt\|";
30	root	1.15	@$rend[$ofs .. $ofs + $len - 1] = ($self->{rs_tab}) x $len
31	root	1.7	if $tab == $self->{cur};
32	root	1.6
33	root	1.7	push @ofs, [ $ofs, $ofs + $len, sub { $_[0]->make_current ($tab) } ];
34	root	1.1
35	root	1.6	$ofs += $len + 1;
36	root	1.1	}
37
38			$self->{tabofs} = \@ofs;
39
40	root	1.7	$self->ROW_t (0, $text, 0, 0, $ncol);
41			$self->ROW_r (0, $rend, 0, 0, $ncol);
42
43			$self->want_refresh;
44	root	1.1	}
45
46			sub new_tab {
47	root	1.21	my ($self, @argv) = @_;
48	root	1.1
49			# save a backlink to us, make sure tabbed is inactive
50			push @urxvt::TERM_INIT, sub {
51			my ($term) = @_;
52			$term->{parent} = $self;
53
54	root	1.25	for (0 .. urxvt::NUM_RESOURCES - 1) {
55			my $value = $self->{resource}[$_];
56
57			$term->resource ("+$_" => $value)
58			if defined $value;
59			}
60	root	1.1
61			$term->resource (perl_ext_2 => $term->resource ("perl_ext_2") . ",-tabbed");
62			};
63
64			push @urxvt::TERM_EXT, urxvt::ext::tabbed::tab::;
65
66			my $term = new urxvt::term
67			$self->env, $urxvt::RXVTNAME,
68			-embed => $self->parent,
69	root	1.21	@argv,
70	root	1.1	;
71			}
72
73			sub configure {
74			my ($self) = @_;
75
76	root	1.5	my $tab = $self->{cur};
77
78	root	1.14	# this is an extremely dirty way to force a configurenotify, but who cares
79	root	1.5	$tab->XMoveResizeWindow (
80			$tab->parent,
81	root	1.14	0, $self->{tabheight} + 1,
82	mikachu	1.30	$self->width, $self->height - $self->{tabheight}
83	root	1.13	);
84			$tab->XMoveResizeWindow (
85			$tab->parent,
86	root	1.4	0, $self->{tabheight},
87	mikachu	1.30	$self->width, $self->height - $self->{tabheight}
88	root	1.1	);
89	root	1.11	}
90
91	root	1.19	sub on_resize_all_windows {
92			my ($self, $width, $height) = @_;
93
94			1
95			}
96
97	root	1.11	sub copy_properties {
98			my ($self) = @_;
99			my $tab = $self->{cur};
100	root	1.5
101			my $wm_normal_hints = $self->XInternAtom ("WM_NORMAL_HINTS");
102
103	root	1.24	my $current = delete $self->{current_properties};
104	root	1.16
105	root	1.24	# pass 1: copy over properties different or nonexisting
106	root	1.5	for my $atom ($tab->XListProperties ($tab->parent)) {
107			my ($type, $format, $items) = $self->XGetWindowProperty ($tab->parent, $atom);
108	sf-exg	1.27
109	root	1.24	# fix up size hints
110	root	1.5	if ($atom == $wm_normal_hints) {
111			my (@hints) = unpack "l!*", $items;
112	sf-exg	1.27
113	root	1.19	$hints[$_] += $self->{tabheight} for (4, 6, 16);
114	sf-exg	1.27
115	root	1.19	$items = pack "l!*", @hints;
116			}
117	root	1.5
118	root	1.24	my $cur = delete $current->{$atom};
119	root	1.6
120	root	1.24	# update if changed, we assume empty items and zero type and format will not happen
121			$self->XChangeProperty ($self->parent, $atom, $type, $format, $items)
122			if $cur->[0] != $type or $cur->[1] != $format or $cur->[2] ne $items;
123
124			$self->{current_properties}{$atom} = [$type, $format, $items];
125	root	1.5	}
126	root	1.6
127	root	1.24	# pass 2, delete all extraneous properties
128			$self->XDeleteProperty ($self->parent, $_) for keys %$current;
129	root	1.1	}
130
131			sub make_current {
132			my ($self, $tab) = @_;
133
134			if (my $cur = $self->{cur}) {
135	root	1.9	delete $cur->{activity};
136	root	1.7	$cur->XUnmapWindow ($cur->parent) if $cur->mapped;
137			$cur->focus_out;
138	root	1.1	}
139	sf-exg	1.27
140	root	1.1	$self->{cur} = $tab;
141
142			$self->configure;
143	root	1.11	$self->copy_properties;
144	sf-exg	1.27
145	root	1.20	$tab->focus_out; # just in case, should be a nop
146			$tab->focus_in if $self->focus;
147	sf-exg	1.27
148	root	1.1	$tab->XMapWindow ($tab->parent);
149	root	1.10	delete $tab->{activity};
150	root	1.1	$self->refresh;
151
152			()
153			}
154
155	root	1.15	sub on_focus_in {
156			my ($self, $event) = @_;
157
158			$self->{cur}->focus_in;
159
160			()
161			}
162
163			sub on_focus_out {
164			my ($self, $event) = @_;
165
166			$self->{cur}->focus_out;
167
168			()
169			}
170
171	sf-exg	1.26	sub on_tt_write {
172			my ($self, $octets) = @_;
173
174			$self->{cur}->tt_write ($octets);
175
176			1
177			}
178
179	root	1.15	sub on_key_press {
180			my ($self, $event) = @_;
181
182			$self->{cur}->key_press ($event->{state}, $event->{keycode}, $event->{time});
183
184			1
185			}
186
187			sub on_key_release {
188			my ($self, $event) = @_;
189
190			$self->{cur}->key_release ($event->{state}, $event->{keycode}, $event->{time});
191
192			1
193			}
194
195	root	1.1	sub on_button_press {
196			1
197			}
198
199			sub on_button_release {
200			my ($self, $event) = @_;
201
202			if ($event->{row} == 0) {
203	root	1.6	for my $button (@{ $self->{tabofs} }) {
204			$button->[2]->($self, $event)
205			if $event->{col} >= $button->[0]
206			&& $event->{col} < $button->[1];
207	root	1.1	}
208			}
209
210			1
211			}
212
213			sub on_motion_notify {
214			1
215			}
216
217			sub on_init {
218			my ($self) = @_;
219
220	root	1.25	$self->{resource} = [map $self->resource ("+$_"), 0 .. urxvt::NUM_RESOURCES - 1];
221	root	1.1
222			$self->resource (int_bwidth => 0);
223	root	1.15	$self->resource (name => "URxvt.tabbed");
224	root	1.1	$self->resource (pty_fd => -1);
225
226			$self->option ($urxvt::OPTION{scrollBar}, 0);
227
228	root	1.15	my $fg = $self->x_resource ("tabbar-fg");
229			my $bg = $self->x_resource ("tabbar-bg");
230			my $tabfg = $self->x_resource ("tab-fg");
231			my $tabbg = $self->x_resource ("tab-bg");
232
233			defined $fg or $fg = 3;
234			defined $bg or $bg = 0;
235			defined $tabfg or $tabfg = 0;
236			defined $tabbg or $tabbg = 1;
237
238			$self->{rs_tabbar} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $fg + 2, $bg + 2);
239			$self->{rs_tab} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $tabfg + 2, $tabbg + 2);
240
241	root	1.1	()
242			}
243
244			sub on_start {
245			my ($self) = @_;
246
247	root	1.4	$self->{tabheight} = $self->int_bwidth + $self->fheight + $self->lineSpace;
248
249	root	1.15	$self->cmd_parse ("\033[?25l");
250
251	root	1.21	my @argv = $self->argv;
252
253			do {
254			shift @argv;
255			} while @argv && $argv[0] ne "-e";
256
257			$self->new_tab (@argv);
258	root	1.1
259			()
260			}
261
262			sub on_configure_notify {
263			my ($self, $event) = @_;
264
265			$self->configure;
266	root	1.12	$self->refresh;
267	root	1.1
268			()
269			}
270
271			sub on_wm_delete_window {
272			my ($self) = @_;
273
274			$_->destroy for @{ $self->{tabs} };
275
276			1
277			}
278
279			sub tab_start {
280			my ($self, $tab) = @_;
281
282	root	1.11	$tab->XChangeInput ($tab->parent, urxvt::PropertyChangeMask);
283
284	root	1.1	push @{ $self->{tabs} }, $tab;
285
286	root	1.7	# $tab->{name} \|\|= scalar @{ $self->{tabs} };
287	root	1.1	$self->make_current ($tab);
288
289			()
290			}
291
292			sub tab_destroy {
293			my ($self, $tab) = @_;
294
295			$self->{tabs} = [ grep $_ != $tab, @{ $self->{tabs} } ];
296
297			if (@{ $self->{tabs} }) {
298			if ($self->{cur} == $tab) {
299			delete $self->{cur};
300			$self->make_current ($self->{tabs}[-1]);
301	root	1.7	} else {
302			$self->refresh;
303	root	1.1	}
304			} else {
305			# delay destruction a tiny bit
306			$self->{destroy} = urxvt::iw->new->start->cb (sub { $self->destroy });
307			}
308
309			()
310			}
311
312	root	1.8	sub tab_key_press {
313			my ($self, $tab, $event, $keysym, $str) = @_;
314
315	root	1.10	if ($event->{state} & urxvt::ShiftMask) {
316			if ($keysym == 0xff51 \|\| $keysym == 0xff53) {
317			my ($idx) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };
318
319			--$idx if $keysym == 0xff51;
320			++$idx if $keysym == 0xff53;
321
322			$self->make_current ($self->{tabs}[$idx % @{ $self->{tabs}}]);
323	sf-exg	1.27
324	root	1.10	return 1;
325			} elsif ($keysym == 0xff54) {
326			$self->new_tab;
327
328			return 1;
329			}
330	root	1.8	}
331	root	1.22	elsif ($event->{state} & urxvt::ControlMask) {
332			if ($keysym == 0xff51 \|\| $keysym == 0xff53) {
333			my ($idx1) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };
334			my $idx2 = ($idx1 + ($keysym == 0xff51 ? -1 : +1)) % @{ $self->{tabs} };
335
336			($self->{tabs}[$idx1], $self->{tabs}[$idx2]) =
337			($self->{tabs}[$idx2], $self->{tabs}[$idx1]);
338
339			$self->make_current ($self->{tabs}[$idx2]);
340
341			return 1;
342			}
343			}
344	root	1.8
345			()
346			}
347
348	root	1.11	sub tab_property_notify {
349			my ($self, $tab, $event) = @_;
350
351			$self->copy_properties
352			if $event->{window} == $tab->parent;
353
354			()
355			}
356
357	root	1.9	sub tab_activity {
358			my ($self, $tab) = @_;
359
360			$self->refresh;
361			}
362
363	root	1.1	package urxvt::ext::tabbed::tab;
364
365			# helper extension implementing the subwindows of a tabbed terminal.
366			# simply proxies all interesting calls back to the tabbed class.
367
368			{
369	root	1.11	for my $hook qw(start destroy key_press property_notify) {
370	root	1.1	eval qq{
371			sub on_$hook {
372			my \$parent = \$_[0]{term}{parent}
373			or return;
374			\$parent->tab_$hook (\@_)
375			}
376			};
377			die if $@;
378			}
379			}
380
381	root	1.9	sub on_add_lines {
382			$_[0]->{activity}++
383			or $_[0]{term}{parent}->tab_activity ($_[0]);
384			()
385			}
386	root	1.1
387