server/lib/cf.pm

package cf;

use Symbol;
use List::Util;
use Storable;
use Opcode;
use Safe;
use Safe::Hole;

use Event;
$Event::Eval = 1; # no idea why this is required, but it is

use strict;

our %COMMAND;
our @EVENT;
our %PROP_TYPE;
our %PROP_IDX;
our $LIBDIR = maps_directory "perl";

BEGIN {
   @EVENT = map lc, @EVENT;

   *CORE::GLOBAL::warn = sub {
      my $msg = join "", @_;
      $msg .= "\n"
         unless $msg =~ /\n$/;

      print STDERR "cfperl: $msg";
      LOG llevError, "cfperl: $msg";
   };
}

my %ignore_set = (MAP_PROP_PATH => 1); # I hate the plug-in api. Deeply!

# generate property mutators
sub prop_gen {
   my ($prefix, $class) = @_;

   no strict 'refs';

   for my $prop (keys %PROP_TYPE) {
      $prop =~ /^\Q$prefix\E_(.*$)/ or next;
      my $sub = lc $1;

      my $type = $PROP_TYPE{$prop};
      my $idx  = $PROP_IDX {$prop};

      *{"$class\::get_$sub"} = *{"$class\::$sub"} = sub {
         $_[0]->get_property ($type, $idx)
      };

      *{"$class\::set_$sub"} = sub {
         $_[0]->set_property ($type, $idx, $_[1]);
      } unless $ignore_set{$prop};
   }
}

# auto-generate most of the API

prop_gen OBJECT_PROP => "cf::object";
# CFAPI_OBJECT_ANIMATION?
prop_gen PLAYER_PROP => "cf::object::player";

prop_gen MAP_PROP    => "cf::map";
prop_gen ARCH_PROP   => "cf::arch";

# guessed hierarchies

@ext::cf::object::player::ISA = @cf::object::player::ISA = 'cf::object';
@ext::cf::object::map::ISA    = @cf::object::map::ISA    = 'cf::object';

# we bless all objects into derived classes to force a method lookup
# within the Safe compartment.
for my $pkg (qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region cf::arch)) {
   no strict 'refs';
   @{"ext::$pkg\::wrap::ISA"} = @{"$pkg\::wrap::ISA"} = $pkg;
}

$Event::DIED = sub {
   warn "error in event callback: @_";
};

my %ext_pkg;
my @exts;
my @hook;
my %command;
my %extcmd;

sub inject_event {
   my $extension = shift;
   my $event_code = shift;

   my $cb = $hook[$event_code]{$extension}
      or return;

   &$cb
}

sub inject_global_event {
   my $event = shift;

   my $cb = $hook[$event]
      or return;

   List::Util::max map &$_, values %$cb
}

sub inject_command {
   my ($name, $obj, $params) = @_;

   for my $cmd (@{ $command{$name} }) {
      $cmd->[1]->($obj, $params);
   }

   -1
}

sub register_command {
   my ($name, $time, $cb) = @_;

   my $caller = caller;
   #warn "registering command '$name/$time' to '$caller'";

   push @{ $command{$name} }, [$time, $cb, $caller];
   $COMMAND{"$name\000"} = List::Util::max map $_->[0], @{ $command{$name} };
}

sub register_extcmd {
   my ($name, $cb) = @_;

   my $caller = caller;
   #warn "registering extcmd '$name' to '$caller'";

   $extcmd{$name} = [$cb, $caller];
}

sub register {
   my ($base, $pkg) = @_;

   for my $idx (0 .. $#EVENT) {
      if (my $ref = $pkg->can ("on_$EVENT[$idx]")) {
         #warn "registering $EVENT[$idx] hook to '$pkg'\n";
         $hook[$idx]{$base} = $ref;
      }
   }
}

sub load_extension {
   my ($path) = @_;

   $path =~ /([^\/\\]+)\.ext$/ or die "$path";
   my $base = $1;
   my $pkg = $1;
   $pkg =~ s/[^[:word:]]/_/g;
   $pkg = "cf::ext::$pkg";

   warn "loading '$path' into '$pkg'\n";

   open my $fh, "<:utf8", $path
      or die "$path: $!";

   my $source =
      "package $pkg; use strict; use utf8;\n"
      . "#line 1 \"$path\"\n{\n"
      . (do { local $/; <$fh> })
      . "\n};\n1";

   eval $source
      or die "$path: $@";

   push @exts, $pkg;
   $ext_pkg{$base} = $pkg;

#   no strict 'refs';
#   @{"$pkg\::ISA"} = ext::;

   register $base, $pkg;
}

sub unload_extension {
   my ($pkg) = @_;

   warn "removing extension $pkg\n";

   # remove hooks
   for my $idx (0 .. $#EVENT) {
      delete $hook[$idx]{$pkg};
   }

   # remove commands
   for my $name (keys %command) {
      my @cb = grep $_->[2] ne $pkg, @{ $command{$name} };

      if (@cb) {
         $command{$name} = \@cb;
         $COMMAND{"$name\000"} = List::Util::max map $_->[0], @cb;
      } else {
         delete $command{$name};
         delete $COMMAND{"$name\000"};
      }
   }

   # remove extcmds
   for my $name (grep $extcmd{$_}[1] eq $pkg, keys %extcmd) {
      delete $extcmd{$name};
   }

   if (my $cb = $pkg->can ("on_unload")) {
      eval {
         $cb->($pkg);
         1
      } or warn "$pkg unloaded, but with errors: $@";
   }

   Symbol::delete_package $pkg;
}

sub load_extensions {
   my $LIBDIR = maps_directory "perl";

   for my $ext (<$LIBDIR/*.ext>) {
      next unless -r $ext;
      eval {
         load_extension $ext;
         1
      } or warn "$ext not loaded: $@";
   }
}

register_command "perl-reload", 0, sub {
   my ($who, $arg) = @_;

   if ($who->flag (FLAG_WIZ)) {
      $who->message ("reloading...");

      warn "reloading...\n";
      eval {
         # 1. cancel all watchers
         $_->cancel for Event::all_watchers;

         # 2. unload all extensions
         for (@exts) {
            $who->message ("unloading <$_>");
            unload_extension $_;
         }

         # 3. unload all modules loaded from $LIBDIR
         while (my ($k, $v) = each %INC) {
            next unless $v =~ /^\Q$LIBDIR\E\/.*\.pm$/;

            $who->message ("removing <$k>");
            delete $INC{$k};

            $k =~ s/\.pm$//;
            $k =~ s/\//::/g;

            if (my $cb = $k->can ("unload_module")) {
               $cb->();
            }

            Symbol::delete_package $k;
         }

         # 4. get rid of ext::, as good as possible
         Symbol::delete_package "ext::$_"
            for qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region);

         # 5. remove register_script_function callbacks
         # TODO
         
         # 6. unload cf.pm "a bit"
         delete $INC{"cf.pm"};

         # don't, removes xs symbols, too
         #Symbol::delete_package __PACKAGE__;

         # 7. reload cf.pm
         $who->message ("reloading cf.pm");
         require cf;
      };
      warn $@ if $@;
      $who->message ($@) if $@;
      warn "reloaded\n";

      $who->message ("reloaded");
   } else {
      $who->message ("Intruder Alert!");
   }
};

#############################################################################
# utility functions

use JSON::Syck (); # TODO# replace by JSON::PC once working

sub from_json($) {
   $JSON::Syck::ImplicitUnicode = 1; # work around JSON::Syck bugs
   JSON::Syck::Load $_[0]
}

sub to_json($) {
   $JSON::Syck::ImplicitUnicode = 0;  # work around JSON::Syck bugs
   JSON::Syck::Dump $_[0]
}

#############################################################################
# extcmd framework, basically convert ext <msg>
# into pkg::->on_extcmd_arg1 (...) while shortcutting a few

sub on_extcmd {
   my ($pl, $buf) = @_;

   my $msg = eval { from_json $buf };

   if (ref $msg) {
      if (my $cb = $extcmd{$msg->{msgtype}}) {
         if (my %reply = $cb->[0]->($pl, $msg)) {
            $pl->ext_reply ($msg->{msgid}, %reply);
         }
      }
   } else {
      warn "player " . ($pl->ob->name) . " sent unparseable ext message: <$buf>\n";
   }

   1
}

#############################################################################
# load/save/clean perl data associated with a map

*on_mapclean = sub {
   my ($map) = @_;

   my $path = $map->tmpname;
   defined $path or return;

   unlink "$path.cfperl";
};

*on_mapin =
*on_mapload = sub {
   my ($map) = @_;

   my $path = $map->tmpname;
   $path = $map->path unless defined $path;

   open my $fh, "<:raw", "$path.cfperl"
      or return; # no perl data

   my $data = Storable::thaw do { local $/; <$fh> };

   $data->{version} <= 1
      or return; # too new

   $map->_set_obs ($data->{obs});
};

*on_mapout = sub {
   my ($map) = @_;

   my $path = $map->tmpname;
   $path = $map->path unless defined $path;

   my $obs = $map->_get_obs;

   if (defined $obs) {
      open my $fh, ">:raw", "$path.cfperl"
         or die "$path.cfperl: $!";

      stat $path;

      print $fh Storable::nfreeze {
         size    => (stat _)[7],
         time    => (stat _)[9],
         version => 1,
         obs     => $obs,
      };

      chmod SAVE_MODE, "$path.cfperl"; # very racy, but cf-compatible *g*
   } else {
      unlink "$path.cfperl";
   }
};

#############################################################################
# load/save perl data associated with player->ob objects

*on_player_load = sub {
   my ($ob, $path) = @_;

   for my $o ($ob, $ob->inv) {
      if (my $value = $o->get_ob_key_value ("_perl_data")) {
         $o->set_ob_key_value ("_perl_data");

         %$o = %{ Storable::thaw pack "H*", $value };
      }
   }
};

*on_player_save = sub {
   my ($ob, $path) = @_;

   $_->set_ob_key_value (_perl_data => unpack "H*", Storable::nfreeze $_)
      for grep %$_, $ob, $ob->inv;
};

#############################################################################
# core extensions - in perl

=item cf::player::exists $login

Returns true when the given account exists.

=cut

sub cf::player::exists($) {
   cf::player::find $_[0]
      or -f sprintf "%s/%s/%s/%s.pl", cf::localdir, cf::playerdir, ($_[0]) x 2;
}

=item $player->reply ($npc, $msg[, $flags])

Sends a message to the player, as if the npc C<$npc> replied. C<$npc>
can be C<undef>. Does the right thing when the player is currently in a
dialogue with the given NPC character.

=cut

# rough implementation of a future "reply" method that works
# with dialog boxes.
sub cf::object::player::reply($$$;$) {
   my ($self, $npc, $msg, $flags) = @_;

   $flags = cf::NDI_BROWN | cf::NDI_UNIQUE unless @_ >= 4;

   if ($self->{record_replies}) {
      push @{ $self->{record_replies} }, [$npc, $msg, $flags];
   } else {
      $msg = $npc->name . " says: $msg" if $npc;
      $self->message ($msg, $flags);
   }
}

=item $player->ext_reply ($msgid, $msgtype, %msg)

Sends an ext reply to the player.

=cut

sub cf::player::ext_reply($$$%) {
   my ($self, $id, %msg) = @_;

   $msg{msgid} = $id;

   $self->send ("ext " . to_json \%msg);
}

#############################################################################
# map scripting support

our $safe = new Safe "ext";
our $safe_hole = new Safe::Hole;

$SIG{FPE} = 'IGNORE';

$safe->permit_only (Opcode::opset qw(:base_core :base_mem :base_orig :base_math sort time));

# here we export the classes and methods available to script code

for (
   ["cf::object"         => qw(contr pay_amount pay_player)],
   ["cf::object::player" => qw(player)],
   ["cf::player"         => qw(peaceful)],
) {
   no strict 'refs';
   my ($pkg, @funs) = @$_;
   *{"ext::$pkg\::$_"} = $safe_hole->wrap (\&{"$pkg\::$_"})
      for @funs;
}

sub safe_eval($;@) {
   my ($code, %vars) = @_;

   my $qcode = $code;
   $qcode =~ s/"/‟/g; # not allowed in #line filenames
   $qcode =~ s/\n/\\n/g;

   local $_;
   local @ext::cf::_safe_eval_args = values %vars;

   $code =
      "do {\n"
      . "my (" . (join ",", map "\$$_", keys %vars) . ") = \@cf::_safe_eval_args;\n"
      . "#line 0 \"{$qcode}\"\n"
      . $code
      . "\n}"
   ;

   sub_generation_inc;
   my @res = wantarray ? $safe->reval ($code) : scalar $safe->reval ($code);
   sub_generation_inc;

   wantarray ? @res : $res[0]
}

sub register_script_function {
   my ($fun, $cb) = @_;

   no strict 'refs';
   *{"ext::$fun"} = $safe_hole->wrap ($cb);
}

#############################################################################
# initialisation

register "<global>", __PACKAGE__;

unshift @INC, $LIBDIR;

load_extensions;

1

Revision:	1.31
Committed:	Mon Aug 14 04:22:04 2006 UTC (20 years, 2 months ago) by elmex
Branch:	MAIN
Changes since 1.30:	+7 -4 lines
Log Message:	fixed bug in cf.pm when unloading extensions. added EVENT_DROP_ON for the trade shops and made query_cost using double
#	User	Rev	Content
1	root	1.1	package cf;
2
3			use Symbol;
4			use List::Util;
5	root	1.6	use Storable;
6	root	1.23	use Opcode;
7			use Safe;
8			use Safe::Hole;
9	root	1.19
10	root	1.18	use Event;
11	root	1.19	$Event::Eval = 1; # no idea why this is required, but it is
12	root	1.1
13			use strict;
14
15			our %COMMAND;
16			our @EVENT;
17			our %PROP_TYPE;
18			our %PROP_IDX;
19	root	1.27	our $LIBDIR = maps_directory "perl";
20	root	1.1
21			BEGIN {
22			@EVENT = map lc, @EVENT;
23
24			*CORE::GLOBAL::warn = sub {
25			my $msg = join "", @_;
26			$msg .= "\n"
27			unless $msg =~ /\n$/;
28
29			print STDERR "cfperl: $msg";
30			LOG llevError, "cfperl: $msg";
31			};
32			}
33
34	root	1.9	my %ignore_set = (MAP_PROP_PATH => 1); # I hate the plug-in api. Deeply!
35
36	root	1.1	# generate property mutators
37			sub prop_gen {
38			my ($prefix, $class) = @_;
39
40			no strict 'refs';
41
42			for my $prop (keys %PROP_TYPE) {
43			$prop =~ /^\Q$prefix\E_(.*$)/ or next;
44			my $sub = lc $1;
45
46			my $type = $PROP_TYPE{$prop};
47			my $idx = $PROP_IDX {$prop};
48
49			{"$class\::get_$sub"} = {"$class\::$sub"} = sub {
50			$_[0]->get_property ($type, $idx)
51			};
52
53			*{"$class\::set_$sub"} = sub {
54			$_[0]->set_property ($type, $idx, $_[1]);
55	root	1.9	} unless $ignore_set{$prop};
56	root	1.1	}
57			}
58
59			# auto-generate most of the API
60
61			prop_gen OBJECT_PROP => "cf::object";
62			# CFAPI_OBJECT_ANIMATION?
63			prop_gen PLAYER_PROP => "cf::object::player";
64
65			prop_gen MAP_PROP => "cf::map";
66			prop_gen ARCH_PROP => "cf::arch";
67
68			# guessed hierarchies
69
70	root	1.25	@ext::cf::object::player::ISA = @cf::object::player::ISA = 'cf::object';
71			@ext::cf::object::map::ISA = @cf::object::map::ISA = 'cf::object';
72
73			# we bless all objects into derived classes to force a method lookup
74			# within the Safe compartment.
75	elmex	1.30	for my $pkg (qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region cf::arch)) {
76	root	1.25	no strict 'refs';
77			@{"ext::$pkg\::wrap::ISA"} = @{"$pkg\::wrap::ISA"} = $pkg;
78			}
79	root	1.1
80	root	1.18	$Event::DIED = sub {
81			warn "error in event callback: @_";
82			};
83
84	root	1.5	my %ext_pkg;
85	root	1.1	my @exts;
86			my @hook;
87			my %command;
88	root	1.15	my %extcmd;
89	root	1.1
90			sub inject_event {
91	root	1.14	my $extension = shift;
92			my $event_code = shift;
93	root	1.1
94	root	1.14	my $cb = $hook[$event_code]{$extension}
95	root	1.5	or return;
96
97	root	1.14	&$cb
98	root	1.5	}
99
100			sub inject_global_event {
101	root	1.12	my $event = shift;
102	root	1.5
103	root	1.12	my $cb = $hook[$event]
104	root	1.1	or return;
105
106	root	1.12	List::Util::max map &$_, values %$cb
107	root	1.1	}
108
109			sub inject_command {
110			my ($name, $obj, $params) = @_;
111
112			for my $cmd (@{ $command{$name} }) {
113			$cmd->[1]->($obj, $params);
114			}
115
116			-1
117			}
118
119			sub register_command {
120			my ($name, $time, $cb) = @_;
121
122			my $caller = caller;
123	root	1.16	#warn "registering command '$name/$time' to '$caller'";
124	root	1.4
125	root	1.1	push @{ $command{$name} }, [$time, $cb, $caller];
126			$COMMAND{"$name\000"} = List::Util::max map $_->[0], @{ $command{$name} };
127			}
128
129	root	1.16	sub register_extcmd {
130			my ($name, $cb) = @_;
131
132			my $caller = caller;
133			#warn "registering extcmd '$name' to '$caller'";
134
135			$extcmd{$name} = [$cb, $caller];
136			}
137
138	root	1.6	sub register {
139			my ($base, $pkg) = @_;
140
141			for my $idx (0 .. $#EVENT) {
142			if (my $ref = $pkg->can ("on_$EVENT[$idx]")) {
143	root	1.16	#warn "registering $EVENT[$idx] hook to '$pkg'\n";
144	root	1.6	$hook[$idx]{$base} = $ref;
145			}
146			}
147			}
148
149	root	1.1	sub load_extension {
150			my ($path) = @_;
151
152			$path =~ /([^\/\\]+)\.ext$/ or die "$path";
153	root	1.5	my $base = $1;
154	root	1.1	my $pkg = $1;
155			$pkg =~ s/[^[:word:]]/_/g;
156			$pkg = "cf::ext::$pkg";
157
158			warn "loading '$path' into '$pkg'\n";
159
160			open my $fh, "<:utf8", $path
161			or die "$path: $!";
162
163			my $source =
164			"package $pkg; use strict; use utf8;\n"
165			. "#line 1 \"$path\"\n{\n"
166			. (do { local $/; <$fh> })
167			. "\n};\n1";
168
169			eval $source
170			or die "$path: $@";
171
172			push @exts, $pkg;
173	root	1.5	$ext_pkg{$base} = $pkg;
174	root	1.1
175	root	1.6	# no strict 'refs';
176	root	1.23	# @{"$pkg\::ISA"} = ext::;
177	root	1.1
178	root	1.6	register $base, $pkg;
179	root	1.1	}
180
181			sub unload_extension {
182			my ($pkg) = @_;
183
184			warn "removing extension $pkg\n";
185
186			# remove hooks
187			for my $idx (0 .. $#EVENT) {
188			delete $hook[$idx]{$pkg};
189			}
190
191			# remove commands
192			for my $name (keys %command) {
193			my @cb = grep $_->[2] ne $pkg, @{ $command{$name} };
194
195			if (@cb) {
196			$command{$name} = \@cb;
197			$COMMAND{"$name\000"} = List::Util::max map $_->[0], @cb;
198			} else {
199			delete $command{$name};
200			delete $COMMAND{"$name\000"};
201			}
202			}
203
204	root	1.15	# remove extcmds
205	root	1.16	for my $name (grep $extcmd{$_}[1] eq $pkg, keys %extcmd) {
206			delete $extcmd{$name};
207	root	1.15	}
208
209	elmex	1.31	if (my $cb = $pkg->can ("on_unload")) {
210			eval {
211			$cb->($pkg);
212			1
213			} or warn "$pkg unloaded, but with errors: $@";
214			}
215
216	root	1.1	Symbol::delete_package $pkg;
217			}
218
219			sub load_extensions {
220			my $LIBDIR = maps_directory "perl";
221
222			for my $ext (<$LIBDIR/*.ext>) {
223	root	1.3	next unless -r $ext;
224	root	1.2	eval {
225			load_extension $ext;
226			1
227			} or warn "$ext not loaded: $@";
228	root	1.1	}
229			}
230
231			register_command "perl-reload", 0, sub {
232			my ($who, $arg) = @_;
233
234			if ($who->flag (FLAG_WIZ)) {
235	root	1.3	$who->message ("reloading...");
236
237	root	1.1	warn "reloading...\n";
238	root	1.4	eval {
239	root	1.27	# 1. cancel all watchers
240	root	1.20	$_->cancel for Event::all_watchers;
241
242	root	1.27	# 2. unload all extensions
243			for (@exts) {
244			$who->message ("unloading <$_>");
245			unload_extension $_;
246			}
247
248			# 3. unload all modules loaded from $LIBDIR
249			while (my ($k, $v) = each %INC) {
250			next unless $v =~ /^\Q$LIBDIR\E\/.*\.pm$/;
251
252			$who->message ("removing <$k>");
253			delete $INC{$k};
254
255			$k =~ s/\.pm$//;
256			$k =~ s/\//::/g;
257
258			if (my $cb = $k->can ("unload_module")) {
259			$cb->();
260			}
261
262			Symbol::delete_package $k;
263			}
264
265			# 4. get rid of ext::, as good as possible
266			Symbol::delete_package "ext::$_"
267			for qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region);
268
269			# 5. remove register_script_function callbacks
270			# TODO
271
272			# 6. unload cf.pm "a bit"
273	root	1.4	delete $INC{"cf.pm"};
274
275			# don't, removes xs symbols, too
276	root	1.21	#Symbol::delete_package __PACKAGE__;
277	root	1.4
278	root	1.27	# 7. reload cf.pm
279			$who->message ("reloading cf.pm");
280	root	1.4	require cf;
281			};
282			warn $@ if $@;
283			$who->message ($@) if $@;
284	root	1.1	warn "reloaded\n";
285	root	1.3
286			$who->message ("reloaded");
287			} else {
288			$who->message ("Intruder Alert!");
289	root	1.1	}
290			};
291
292	root	1.8	#############################################################################
293	root	1.28	# utility functions
294
295			use JSON::Syck (); # TODO# replace by JSON::PC once working
296
297			sub from_json($) {
298	root	1.29	$JSON::Syck::ImplicitUnicode = 1; # work around JSON::Syck bugs
299	root	1.28	JSON::Syck::Load $_[0]
300			}
301
302			sub to_json($) {
303	root	1.29	$JSON::Syck::ImplicitUnicode = 0; # work around JSON::Syck bugs
304	root	1.28	JSON::Syck::Dump $_[0]
305			}
306
307			#############################################################################
308			# extcmd framework, basically convert ext <msg>
309	root	1.15	# into pkg::->on_extcmd_arg1 (...) while shortcutting a few
310
311			sub on_extcmd {
312			my ($pl, $buf) = @_;
313
314	root	1.28	my $msg = eval { from_json $buf };
315
316			if (ref $msg) {
317			if (my $cb = $extcmd{$msg->{msgtype}}) {
318			if (my %reply = $cb->[0]->($pl, $msg)) {
319			$pl->ext_reply ($msg->{msgid}, %reply);
320			}
321			}
322			} else {
323			warn "player " . ($pl->ob->name) . " sent unparseable ext message: <$buf>\n";
324			}
325	root	1.15
326	root	1.28	1
327	root	1.15	}
328
329			#############################################################################
330	root	1.8	# load/save/clean perl data associated with a map
331
332	root	1.7	*on_mapclean = sub {
333	root	1.13	my ($map) = @_;
334	root	1.7
335			my $path = $map->tmpname;
336			defined $path or return;
337
338			unlink "$path.cfperl";
339			};
340
341	root	1.6	*on_mapin =
342			*on_mapload = sub {
343	root	1.13	my ($map) = @_;
344	root	1.6
345			my $path = $map->tmpname;
346			$path = $map->path unless defined $path;
347
348			open my $fh, "<:raw", "$path.cfperl"
349			or return; # no perl data
350
351			my $data = Storable::thaw do { local $/; <$fh> };
352
353			$data->{version} <= 1
354			or return; # too new
355
356			$map->_set_obs ($data->{obs});
357			};
358
359			*on_mapout = sub {
360	root	1.13	my ($map) = @_;
361	root	1.6
362			my $path = $map->tmpname;
363			$path = $map->path unless defined $path;
364
365			my $obs = $map->_get_obs;
366
367			if (defined $obs) {
368			open my $fh, ">:raw", "$path.cfperl"
369			or die "$path.cfperl: $!";
370
371	root	1.8	stat $path;
372
373			print $fh Storable::nfreeze {
374			size => (stat _)[7],
375			time => (stat _)[9],
376			version => 1,
377			obs => $obs,
378			};
379
380			chmod SAVE_MODE, "$path.cfperl"; # very racy, but cf-compatible g
381			} else {
382			unlink "$path.cfperl";
383			}
384			};
385
386			#############################################################################
387			# load/save perl data associated with player->ob objects
388
389			*on_player_load = sub {
390	root	1.13	my ($ob, $path) = @_;
391	root	1.8
392	root	1.11	for my $o ($ob, $ob->inv) {
393			if (my $value = $o->get_ob_key_value ("_perl_data")) {
394			$o->set_ob_key_value ("_perl_data");
395
396			%$o = %{ Storable::thaw pack "H*", $value };
397			}
398			}
399	root	1.8	};
400
401			*on_player_save = sub {
402	root	1.13	my ($ob, $path) = @_;
403	root	1.8
404	root	1.11	$_->set_ob_key_value (_perl_data => unpack "H*", Storable::nfreeze $_)
405			for grep %$_, $ob, $ob->inv;
406	root	1.6	};
407
408	root	1.22	#############################################################################
409			# core extensions - in perl
410
411	root	1.23	=item cf::player::exists $login
412
413			Returns true when the given account exists.
414
415			=cut
416
417			sub cf::player::exists($) {
418			cf::player::find $_[0]
419			or -f sprintf "%s/%s/%s/%s.pl", cf::localdir, cf::playerdir, ($_[0]) x 2;
420			}
421
422	root	1.28	=item $player->reply ($npc, $msg[, $flags])
423
424			Sends a message to the player, as if the npc C<$npc> replied. C<$npc>
425			can be C<undef>. Does the right thing when the player is currently in a
426			dialogue with the given NPC character.
427
428			=cut
429
430	root	1.22	# rough implementation of a future "reply" method that works
431			# with dialog boxes.
432	root	1.23	sub cf::object::player::reply($$$;$) {
433			my ($self, $npc, $msg, $flags) = @_;
434
435			$flags = cf::NDI_BROWN \| cf::NDI_UNIQUE unless @_ >= 4;
436	root	1.22
437	root	1.24	if ($self->{record_replies}) {
438			push @{ $self->{record_replies} }, [$npc, $msg, $flags];
439			} else {
440			$msg = $npc->name . " says: $msg" if $npc;
441			$self->message ($msg, $flags);
442			}
443	root	1.22	}
444
445	root	1.28	=item $player->ext_reply ($msgid, $msgtype, %msg)
446
447			Sends an ext reply to the player.
448
449			=cut
450
451			sub cf::player::ext_reply($$$%) {
452			my ($self, $id, %msg) = @_;
453
454			$msg{msgid} = $id;
455
456			$self->send ("ext " . to_json \%msg);
457			}
458
459	root	1.22	#############################################################################
460	root	1.23	# map scripting support
461
462			our $safe = new Safe "ext";
463			our $safe_hole = new Safe::Hole;
464
465			$SIG{FPE} = 'IGNORE';
466
467			$safe->permit_only (Opcode::opset qw(:base_core :base_mem :base_orig :base_math sort time));
468
469	root	1.25	# here we export the classes and methods available to script code
470
471			for (
472	root	1.27	["cf::object" => qw(contr pay_amount pay_player)],
473	root	1.25	["cf::object::player" => qw(player)],
474			["cf::player" => qw(peaceful)],
475			) {
476			no strict 'refs';
477			my ($pkg, @funs) = @$_;
478			*{"ext::$pkg\::$_"} = $safe_hole->wrap (\&{"$pkg\::$_"})
479			for @funs;
480			}
481	root	1.23
482			sub safe_eval($;@) {
483			my ($code, %vars) = @_;
484
485			my $qcode = $code;
486			$qcode =~ s/"/‟/g; # not allowed in #line filenames
487			$qcode =~ s/\n/\\n/g;
488
489			local $_;
490			local @ext::cf::_safe_eval_args = values %vars;
491
492	root	1.25	$code =
493	root	1.23	"do {\n"
494			. "my (" . (join ",", map "\$$_", keys %vars) . ") = \@cf::_safe_eval_args;\n"
495			. "#line 0 \"{$qcode}\"\n"
496			. $code
497			. "\n}"
498	root	1.25	;
499
500			sub_generation_inc;
501			my @res = wantarray ? $safe->reval ($code) : scalar $safe->reval ($code);
502			sub_generation_inc;
503
504			wantarray ? @res : $res[0]
505	root	1.23	}
506
507			sub register_script_function {
508			my ($fun, $cb) = @_;
509
510			no strict 'refs';
511			*{"ext::$fun"} = $safe_hole->wrap ($cb);
512			}
513
514			#############################################################################
515	root	1.22	# initialisation
516
517	root	1.6	register "<global>", __PACKAGE__;
518
519	root	1.27	unshift @INC, $LIBDIR;
520	root	1.17
521	root	1.1	load_extensions;
522
523			1
524