[ViewVC] Annotation of: cvs/cfmaps/cfmap2png

#!/opt/bin/perl

# bugs: http://cfmaps.schmorp.de/brest/apartments/brest_town_house.html <- walls
# whaling... icecaves... water is red?
# tower of stars: missing craters?
# http://cfmaps.schmorp.de/pup_land/raffle/raffle3_u2.html <-> yellow "doors" show as grey stone as surrounding

use strict;

use Storable;
use List::Util qw(max);

use Gtk2;

#init Gtk2::Gdk;

my $LIB = $ENV{CROSSFIRE_LIBDIR}
   or die "\$CROSSFIRE_LIBDIR must be set\n";

sub T (){ 32 }

sub read_pak($) {
   my ($path) = @_;

   eval {
      -M "$path.pst" < -M $path
      && Storable::retrieve "$path.pst"
   } or do {
      my %pak;

      open my $fh, "<:raw", $path
         or die "$_[0]: $!";
      while (<$fh>) {
         my ($type, $id, $len, $path) = split;
         $path =~ s/.*\///;
         read $fh, $pak{$path}, $len;
      }

      Storable::nstore \%pak, "$path.pst";

      \%pak
   }
}

sub read_smooth($) {
   my ($path) = @_;

   eval {
      -M "$path.pst" < -M $path
      && Storable::retrieve "$path.pst"
   } or do {
      my %smooth;

      open my $fh, "<:raw", $path
         or die "$path: $!";
      while (<$fh>) {
         next if /^\s*($|#)/;

         $smooth{$1} = $2 if /^(\S+)\s+(\S+)$/;
      }

      Storable::nstore \%smooth, "$path.pst";

      \%smooth
   }
}

sub read_arch($;$) {
   my ($path, $cache) = @_;

   eval {
      $cache
      && -M "$path.pst" < -M $path
      && Storable::retrieve "$path.pst"
   } or do {
      my %arc;
      my ($more, $prev);

      open my $fh, "<:raw", $path
         or die "$path: $!";

      my $parse_block; $parse_block = sub {
         my %arc = @_;

         while (<$fh>) {
            s/\s+$//;
            if (/^end$/i) {
               last;
            } elsif (/^arch (\S+)$/) {
               push @{ $arc{subarch} }, $parse_block->(_name => $1);
            } elsif (/^msg$/) {
               while (<$fh>) {
                  last if /^endmsg\s*$/i;
                  $arc{msg} .= $_;
               }
            } elsif (/^(\S+)\s*(.*)$/) {
               $arc{lc $1} = $2;
            } elsif (/^\s*($|#)/) {
               #
            } else {
               warn "$path: unparsable line '$_' in arch $arc{_name}";
            }
         }

         \%arc
      };

      while (<$fh>) {
         s/\s+$//;
         if (/^more$/i) {
            $more = $prev;
         } elsif (/^object (\S+)$/i) {
            my $name = $1;
            my $arc = $parse_block->(_name => $name);

            $arc{$name} = $arc;
            $more->{more} = $arc if $more;
            
            $prev = $arc;
            $more = undef;
         } elsif (/^arch (\S+)$/i) {
            push @{ $arc{arch} }, $parse_block->(_name => $1);
         } elsif (/^\s*($|#)/) {
            #
         } else {
            warn "$path: unparseable top-level line '$_'";
         }
      }

      undef $parse_block; # work around bug in perl not freeing $fh etc.

      Storable::nstore \%arc, "$path.pst"
         if $cache;

      \%arc
   }
}

my $arch   = read_arch   "$LIB/archetypes", 1;
my $tile   = read_pak    "$LIB/crossfire.0";
my $smooth = read_smooth "$LIB/smooth";

sub tile($) {
   my $name = $_[0];

   my $pb = $tile->{$name}
      or return;

   unless (ref $pb) {
      my $file = "/tmp/map2png.$$~";

      open my $fh, ">:raw", $file
         or die "$file: $!";
      print $fh $pb;
      close $fh;

      $pb = $tile->{$name} = new_from_file Gtk2::Gdk::Pixbuf $file;
      unlink $file;
   }

   $pb
}

sub cfmap_render($;$) {
   my ($mapa, $mapname) = @_;

   my %meta;

   my ($mapx, $mapy);

   my $map = $meta{map} = [];

   for (@{ $mapa->{arch} }) {
      if ($_->{_name} eq "map") {
         $meta{info} = $_;

         $mapx = $_->{width}  || $_->{x};
         $mapy = $_->{height} || $_->{y};
      } else {
         push @{ $map->[$_->{x}][$_->{y}] }, $_;

         # arch map is unreliable w.r.t. width and height
         $mapx = $_->{x} + 1 if $mapx <= $_->{x};
         $mapy = $_->{y} + 1 if $mapy <= $_->{y};
         #$mapx = $a->{x} + 1, warn "$mapname: arch '$a->{_name}' outside map width at ($a->{x}|$a->{y})\n" if $mapx <= $a->{x};
         #$mapy = $a->{y} + 1, warn "$mapname: arch '$a->{_name}' outside map height at ($a->{x}|$a->{y})\n" if $mapy <= $a->{y};
      }
   }

   $meta{width}  = $mapx;
   $meta{height} = $mapy;

   my %map_face;
   my %draw_info;

   my $OBJ_LEVEL = 2**32; # higher than any valid (or in-use) smooth_level

   # first pass, gather face stacking order, border and corner info
   for my $x (0 .. $mapx - 1) {
      my $col = $map->[$x];
      for my $y (0 .. $mapy - 1) {
         my $as = $col->[$y] || [];
         
         for my $layer (0 .. $#$as) {
            my $a = $as->[$layer];

            my $o = $arch->{$a->{_name}}
               or (warn "$mapname: arch '$a->{_name}' not found at ($x|$y)\n"), next;

            $o = $arch->{$o->{other_arch}} while $o->{other_arch} && !$o->{face};

            $o or die "arch $a->{_name} undefined at ($x|$y)\n";

            my $smooth_level = $o->{smoothlevel};
            my $level        = $smooth_level  ? $smooth_level
                             : $o->{is_floor} ? 0
                             :                  $OBJ_LEVEL + $layer;

            while ($o) {
               my $pb = tile $o->{face}
                  or (warn "$mapname: face '$o->{face}' not found for arch '$a->{_name}' at ($x|$y)\n"), last;

               my $mx = $x + $o->{x};
               my $my = $y + $o->{y};

               last if $mx >= $mapx
                    || $my >= $mapy;

               # this is very ugly (some tiles are 32x33 or worse)
               my $bigface = $pb->get_width >= T*2 || $pb->get_height >= T*2;

               if (my $sface = $smooth->{$o->{face}}) {
                  $bigface and die "can't handle big faces with smoothing ($o->{face})\n";

                  # full tile
                  $draw_info{$smooth_level}{$sface}{$mx    , $my    } |= 0x1000;

                  # borders
                  $draw_info{$smooth_level}{$sface}{$mx + 1, $my    } |= 0x0031;
                  $draw_info{$smooth_level}{$sface}{$mx    , $my + 1} |= 0x0092;
                  $draw_info{$smooth_level}{$sface}{$mx - 1, $my    } |= 0x0064;
                  $draw_info{$smooth_level}{$sface}{$mx    , $my - 1} |= 0x00c8;

                  # corners
                  $draw_info{$smooth_level}{$sface}{$mx + 1, $my + 1} |= 0x0100;
                  $draw_info{$smooth_level}{$sface}{$mx - 1, $my + 1} |= 0x0200;
                  $draw_info{$smooth_level}{$sface}{$mx - 1, $my - 1} |= 0x0400;
                  $draw_info{$smooth_level}{$sface}{$mx + 1, $my - 1} |= 0x0800;
               } else {
                  $smooth_level = 0;
               }

               my $dx = $bigface ? $o->{x} : 0;
               my $dy = $bigface ? $o->{y} : 0;

               $draw_info{$level}{$o->{face}}{$mx, $my} |= 0x2000 | (($dx + 128) << 24) | (($dy + 128) << 16);

               $o = $o->{more};
            }
         }
      }
   }

   my $map_pb = new Gtk2::Gdk::Pixbuf "rgb", 1, 8, $mapx * T, $mapy * T
         or die;
   $map_pb->fill (0x00000000);

   # second pass, render all the stuff
   for my $level (sort { $a <=> $b } keys %draw_info) {
      my $v = $draw_info{$level};
      while (my ($sface, $info) = each %$v) {
         my $pb = tile $sface
            or die "no smooth face $sface\n";

         while (my ($xy, $bits) = each %$info) {
            my ($x, $y) = split $;, $xy;

            next if $x < 0 || $x >= $mapx
                 || $y < 0 || $y >= $mapy;

            # bits is 00XX XXXX YYYY YYFX cccc CCCC BBBB
            # X  don't draw
            # F  full tile draw with x|y bigface displacement
            # c  maybe draw these corners
            # C  do not draw these corners
            # b  draw these borders

            if ($bits & 0x2000) {
               my $dx = (($bits >> 24) & 0xff) - 128;
               my $dy = (($bits >> 16) & 0xff) - 128;

               $pb->composite ($map_pb,
                  $x * T, $y * T,
                  T, T,
                  ($x - $dx) * T, ($y - $dy) * T, 1, 1,
                  "nearest",
                  255
               );
            }

            unless ($bits & 0x1000) {
               my $border = $bits & 0xf;
               my $corner = ($bits >> 8) & ~($bits >> 4) & 0xf;

               $pb->composite ($map_pb,
                  $x * T, $y * T,
                  T, T,
                  ($x - $border) * T, $y * T, 1, 1,
                  "nearest",
                  255
               ) if $border;

               $pb->composite ($map_pb,
                  $x * T, $y * T,
                  T, T,
                  ($x - $corner) * T, ($y - 1) * T, 1, 1,
                  "nearest",
                  255
               ) if $corner;
            }
         }
      }
   }

   ($map_pb, \%meta)
}

for my $file (@ARGV) {
   my $mapa = read_arch $file;
   my ($pb, $meta) = cfmap_render $mapa, $file;
   $pb->save ("$file.png", "png");
   Storable::nstore $meta, "$file.pst";
}


Revision:	1.1
Committed:	Thu Nov 17 11:51:08 2005 UTC (18 years, 6 months ago) by root
Branch:	MAIN
Log Message:	* empty log message *
#	User	Rev	Content
1	root	1.1	#!/opt/bin/perl
2
3			# bugs: http://cfmaps.schmorp.de/brest/apartments/brest_town_house.html <- walls
4			# whaling... icecaves... water is red?
5			# tower of stars: missing craters?
6			# http://cfmaps.schmorp.de/pup_land/raffle/raffle3_u2.html <-> yellow "doors" show as grey stone as surrounding
7
8			use strict;
9
10			use Storable;
11			use List::Util qw(max);
12
13			use Gtk2;
14
15			#init Gtk2::Gdk;
16
17			my $LIB = $ENV{CROSSFIRE_LIBDIR}
18			or die "\$CROSSFIRE_LIBDIR must be set\n";
19
20			sub T (){ 32 }
21
22			sub read_pak($) {
23			my ($path) = @_;
24
25			eval {
26			-M "$path.pst" < -M $path
27			&& Storable::retrieve "$path.pst"
28			} or do {
29			my %pak;
30
31			open my $fh, "<:raw", $path
32			or die "$_[0]: $!";
33			while (<$fh>) {
34			my ($type, $id, $len, $path) = split;
35			$path =~ s/.*\///;
36			read $fh, $pak{$path}, $len;
37			}
38
39			Storable::nstore \%pak, "$path.pst";
40
41			\%pak
42			}
43			}
44
45			sub read_smooth($) {
46			my ($path) = @_;
47
48			eval {
49			-M "$path.pst" < -M $path
50			&& Storable::retrieve "$path.pst"
51			} or do {
52			my %smooth;
53
54			open my $fh, "<:raw", $path
55			or die "$path: $!";
56			while (<$fh>) {
57			next if /^\s*($\|#)/;
58
59			$smooth{$1} = $2 if /^(\S+)\s+(\S+)$/;
60			}
61
62			Storable::nstore \%smooth, "$path.pst";
63
64			\%smooth
65			}
66			}
67
68			sub read_arch($;$) {
69			my ($path, $cache) = @_;
70
71			eval {
72			$cache
73			&& -M "$path.pst" < -M $path
74			&& Storable::retrieve "$path.pst"
75			} or do {
76			my %arc;
77			my ($more, $prev);
78
79			open my $fh, "<:raw", $path
80			or die "$path: $!";
81
82			my $parse_block; $parse_block = sub {
83			my %arc = @_;
84
85			while (<$fh>) {
86			s/\s+$//;
87			if (/^end$/i) {
88			last;
89			} elsif (/^arch (\S+)$/) {
90			push @{ $arc{subarch} }, $parse_block->(_name => $1);
91			} elsif (/^msg$/) {
92			while (<$fh>) {
93			last if /^endmsg\s*$/i;
94			$arc{msg} .= $_;
95			}
96			} elsif (/^(\S+)\s(.)$/) {
97			$arc{lc $1} = $2;
98			} elsif (/^\s*($\|#)/) {
99			#
100			} else {
101			warn "$path: unparsable line '$_' in arch $arc{_name}";
102			}
103			}
104
105			\%arc
106			};
107
108			while (<$fh>) {
109			s/\s+$//;
110			if (/^more$/i) {
111			$more = $prev;
112			} elsif (/^object (\S+)$/i) {
113			my $name = $1;
114			my $arc = $parse_block->(_name => $name);
115
116			$arc{$name} = $arc;
117			$more->{more} = $arc if $more;
118
119			$prev = $arc;
120			$more = undef;
121			} elsif (/^arch (\S+)$/i) {
122			push @{ $arc{arch} }, $parse_block->(_name => $1);
123			} elsif (/^\s*($\|#)/) {
124			#
125			} else {
126			warn "$path: unparseable top-level line '$_'";
127			}
128			}
129
130			undef $parse_block; # work around bug in perl not freeing $fh etc.
131
132			Storable::nstore \%arc, "$path.pst"
133			if $cache;
134
135			\%arc
136			}
137			}
138
139			my $arch = read_arch "$LIB/archetypes", 1;
140			my $tile = read_pak "$LIB/crossfire.0";
141			my $smooth = read_smooth "$LIB/smooth";
142
143			sub tile($) {
144			my $name = $_[0];
145
146			my $pb = $tile->{$name}
147			or return;
148
149			unless (ref $pb) {
150			my $file = "/tmp/map2png.$$~";
151
152			open my $fh, ">:raw", $file
153			or die "$file: $!";
154			print $fh $pb;
155			close $fh;
156
157			$pb = $tile->{$name} = new_from_file Gtk2::Gdk::Pixbuf $file;
158			unlink $file;
159			}
160
161			$pb
162			}
163
164			sub cfmap_render($;$) {
165			my ($mapa, $mapname) = @_;
166
167			my %meta;
168
169			my ($mapx, $mapy);
170
171			my $map = $meta{map} = [];
172
173			for (@{ $mapa->{arch} }) {
174			if ($_->{_name} eq "map") {
175			$meta{info} = $_;
176
177			$mapx = $_->{width} \|\| $_->{x};
178			$mapy = $_->{height} \|\| $_->{y};
179			} else {
180			push @{ $map->[$_->{x}][$_->{y}] }, $_;
181
182			# arch map is unreliable w.r.t. width and height
183			$mapx = $_->{x} + 1 if $mapx <= $_->{x};
184			$mapy = $_->{y} + 1 if $mapy <= $_->{y};
185			#$mapx = $a->{x} + 1, warn "$mapname: arch '$a->{_name}' outside map width at ($a->{x}\|$a->{y})\n" if $mapx <= $a->{x};
186			#$mapy = $a->{y} + 1, warn "$mapname: arch '$a->{_name}' outside map height at ($a->{x}\|$a->{y})\n" if $mapy <= $a->{y};
187			}
188			}
189
190			$meta{width} = $mapx;
191			$meta{height} = $mapy;
192
193			my %map_face;
194			my %draw_info;
195
196			my $OBJ_LEVEL = 2**32; # higher than any valid (or in-use) smooth_level
197
198			# first pass, gather face stacking order, border and corner info
199			for my $x (0 .. $mapx - 1) {
200			my $col = $map->[$x];
201			for my $y (0 .. $mapy - 1) {
202			my $as = $col->[$y] \|\| [];
203
204			for my $layer (0 .. $#$as) {
205			my $a = $as->[$layer];
206
207			my $o = $arch->{$a->{_name}}
208			or (warn "$mapname: arch '$a->{_name}' not found at ($x\|$y)\n"), next;
209
210			$o = $arch->{$o->{other_arch}} while $o->{other_arch} && !$o->{face};
211
212			$o or die "arch $a->{_name} undefined at ($x\|$y)\n";
213
214			my $smooth_level = $o->{smoothlevel};
215			my $level = $smooth_level ? $smooth_level
216			: $o->{is_floor} ? 0
217			: $OBJ_LEVEL + $layer;
218
219			while ($o) {
220			my $pb = tile $o->{face}
221			or (warn "$mapname: face '$o->{face}' not found for arch '$a->{_name}' at ($x\|$y)\n"), last;
222
223			my $mx = $x + $o->{x};
224			my $my = $y + $o->{y};
225
226			last if $mx >= $mapx
227			\|\| $my >= $mapy;
228
229			# this is very ugly (some tiles are 32x33 or worse)
230			my $bigface = $pb->get_width >= T2 \|\| $pb->get_height >= T2;
231
232			if (my $sface = $smooth->{$o->{face}}) {
233			$bigface and die "can't handle big faces with smoothing ($o->{face})\n";
234
235			# full tile
236			$draw_info{$smooth_level}{$sface}{$mx , $my } \|= 0x1000;
237
238			# borders
239			$draw_info{$smooth_level}{$sface}{$mx + 1, $my } \|= 0x0031;
240			$draw_info{$smooth_level}{$sface}{$mx , $my + 1} \|= 0x0092;
241			$draw_info{$smooth_level}{$sface}{$mx - 1, $my } \|= 0x0064;
242			$draw_info{$smooth_level}{$sface}{$mx , $my - 1} \|= 0x00c8;
243
244			# corners
245			$draw_info{$smooth_level}{$sface}{$mx + 1, $my + 1} \|= 0x0100;
246			$draw_info{$smooth_level}{$sface}{$mx - 1, $my + 1} \|= 0x0200;
247			$draw_info{$smooth_level}{$sface}{$mx - 1, $my - 1} \|= 0x0400;
248			$draw_info{$smooth_level}{$sface}{$mx + 1, $my - 1} \|= 0x0800;
249			} else {
250			$smooth_level = 0;
251			}
252
253			my $dx = $bigface ? $o->{x} : 0;
254			my $dy = $bigface ? $o->{y} : 0;
255
256			$draw_info{$level}{$o->{face}}{$mx, $my} \|= 0x2000 \| (($dx + 128) << 24) \| (($dy + 128) << 16);
257
258			$o = $o->{more};
259			}
260			}
261			}
262			}
263
264			my $map_pb = new Gtk2::Gdk::Pixbuf "rgb", 1, 8, $mapx * T, $mapy * T
265			or die;
266			$map_pb->fill (0x00000000);
267
268			# second pass, render all the stuff
269			for my $level (sort { $a <=> $b } keys %draw_info) {
270			my $v = $draw_info{$level};
271			while (my ($sface, $info) = each %$v) {
272			my $pb = tile $sface
273			or die "no smooth face $sface\n";
274
275			while (my ($xy, $bits) = each %$info) {
276			my ($x, $y) = split $;, $xy;
277
278			next if $x < 0 \|\| $x >= $mapx
279			\|\| $y < 0 \|\| $y >= $mapy;
280
281			# bits is 00XX XXXX YYYY YYFX cccc CCCC BBBB
282			# X don't draw
283			# F full tile draw with x\|y bigface displacement
284			# c maybe draw these corners
285			# C do not draw these corners
286			# b draw these borders
287
288			if ($bits & 0x2000) {
289			my $dx = (($bits >> 24) & 0xff) - 128;
290			my $dy = (($bits >> 16) & 0xff) - 128;
291
292			$pb->composite ($map_pb,
293			$x * T, $y * T,
294			T, T,
295			($x - $dx) * T, ($y - $dy) * T, 1, 1,
296			"nearest",
297			255
298			);
299			}
300
301			unless ($bits & 0x1000) {
302			my $border = $bits & 0xf;
303			my $corner = ($bits >> 8) & ~($bits >> 4) & 0xf;
304
305			$pb->composite ($map_pb,
306			$x * T, $y * T,
307			T, T,
308			($x - $border) * T, $y * T, 1, 1,
309			"nearest",
310			255
311			) if $border;
312
313			$pb->composite ($map_pb,
314			$x * T, $y * T,
315			T, T,
316			($x - $corner) * T, ($y - 1) * T, 1, 1,
317			"nearest",
318			255
319			) if $corner;
320			}
321			}
322			}
323			}
324
325			($map_pb, \%meta)
326			}
327
328			for my $file (@ARGV) {
329			my $mapa = read_arch $file;
330			my ($pb, $meta) = cfmap_render $mapa, $file;
331			$pb->save ("$file.png", "png");
332			Storable::nstore $meta, "$file.pst";
333			}
334
335
336
337
338
339